# $Id: PKGBUILD 147903 2012-01-28 10:36:44Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgbase=kdetoys
pkgname=('kdetoys-amor'
         'kdetoys-kteatime'
         'kdetoys-ktux')
pkgver=4.8.0
pkgrel=1
arch=('i686' 'x86_64' 'mips64el')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdetoys')
makedepends=('cmake' 'automoc4' 'kdebase-workspace')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
sha1sums=('4d583cf52d10462a71df8eba907c07453f844cb2')

build() {
	cd $srcdir
	mkdir build
	cd build
	cmake ../${pkgbase}-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_INSTALL_PREFIX=/usr
	make
}

package_kdetoys-amor() {
	pkgdesc='On-Screen Creature'
	depends=('kdebase-runtime')
	install='kdetoys.install'
	cd $srcdir/build/amor
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/amor
	make DESTDIR=$pkgdir install
}

package_kdetoys-kteatime() {
	pkgdesc='Tea Cooker'
	depends=('kdebase-runtime')
	install='kdetoys.install'
	cd $srcdir/build/kteatime
	make DESTDIR=$pkgdir install
	cd $srcdir/build/doc/kteatime
	make DESTDIR=$pkgdir install
}

package_kdetoys-ktux() {
	pkgdesc='KTux'
	depends=('kdebase-workspace' )
	install='kdetoys.install'
	cd $srcdir/build/ktux
	make DESTDIR=$pkgdir install
}