# $Id: PKGBUILD 110362 2011-02-19 03:39:03Z allan $
# Contributor: Camille Moncelier <pix@devlife.org>, simo <simo@archlinux.org>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>

pkgname=kexec-tools
pkgver=2.0.2
pkgrel=3
pkgdesc="Load another kernel from the currently executing Linux kernel"
arch=('i686' 'x86_64')
url="http://kernel.org/pub/linux/utils/kernel/kexec/"
source=("http://kernel.org/pub/linux/utils/kernel/kexec/kexec-tools-${pkgver}.tar.bz2"
        'kexec' 'kexec.conf.d')
depends=('gawk')
makedepends=('zlib' 'xz')
backup=('etc/conf.d/kexec')
license=('GPL2')
md5sums=('35d05fed1c97008ac34c5bfb929295eb'
         '15599234f174ddc4d2611f32effec6ab'
         'b9ddfb9fbcc7e4e7e7294fe94fa60aeb')

build() {
  cd $srcdir/$pkgname-$pkgver
  export LDFLAGS+=" -static"
  ./configure --prefix=/usr
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install

  mv $pkgdir/usr/sbin $pkgdir/sbin

  install -D -m644 kexec/kexec.8 $pkgdir/usr/share/man/man8/kexec.8
  install -D -m644 $srcdir/kexec.conf.d $pkgdir/etc/conf.d/kexec
  install -D -m755 $srcdir/kexec $pkgdir/etc/rc.d/kexec
}