# $Id: PKGBUILD 187862 2013-06-07 09:24:58Z tomegun $
# Maintainer:
# Contributor: Angel Velasquez <angvp@archlinux.org> 
# Contributor: Jason Chu <jason@archlinux.org>
# Contributor: Juergen Hoetzel <jason@archlinux.org>

pkgname=kismet
pkgver=2013_03_R1b
_realver="${pkgver//_/-}"
pkgrel=2
pkgdesc="802.11 layer2 wireless network detector, sniffer, and intrusion detection system"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.kismetwireless.net/"
license=('GPL')
depends=('libpcap' 'pcre' 'bluez-libs' 'libcap')
optdepends=('gpsd: log coordinates of detected networks'
            'wireshark-cli: provide OUI files used to determine device manufacturer'
            'wireshark-cli: mergecap, to merge multiple capture files'
            'sox: provide the default kismet sound playback binary'
            'festival: text-to-speech support'
            'flite:  alternative/lightweight text-to-speech support'
            'ruby: ruby interface')
backup=('etc/kismet.conf' 'etc/kismet_drone.conf')
install=kismet.install
changelog=kismet.changelog
source=("http://www.kismetwireless.net/code/${pkgname}-${_realver}.tar.gz"{,.asc})
md5sums=('6cdcd78baf2e15edbe8a9de3c5493f02'
         'SKIP')

build() {
    cd "${srcdir}/${pkgname}-${_realver}"

    ./configure --prefix=/usr \
                --sysconfdir=/etc \
                --localstatedir=/var \
		--build=$CHOST --host=$CHOST
    make dep
    make

    # Include plugins bundled with kismet
    make plugins
}

package() {
    cd "${srcdir}/${pkgname}-${_realver}"

    # Install kismet
    make DESTDIR="$pkgdir" install

    # Install plugins
    make plugins-install DESTDIR="$pkgdir"

    # the README is very comprehensive, a good idea to include it
    install -D -m 644 "${srcdir}/kismet-${_realver}/README" "${pkgdir}/usr/share/kismet/README"

    # Our own suid-install, first half (see kismet.install)
    install -o "root" -g "root" -m 4550 kismet_capture "${pkgdir}/usr/bin/"
}