# $Id: PKGBUILD 144356 2011-12-05 01:48:51Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: James Rayner <iphitus@gmail.com>
# Contributor: Sergio Jovani Guzman <moret@paretux.org>

pkgname=konversation
pkgver=1.4
pkgrel=1
pkgdesc="A user friendly IRC client for KDE"
arch=('i686' 'x86_64')
url="http://konversation.kde.org"
depends=('kdebase-runtime' 'kdepimlibs' 'python')
makedepends=('automoc4' 'cmake' 'pkgconfig' 'docbook-xml')
license=('GPL2' 'FDL')
install=${pkgname}.install
options=('!makeflags')
source=("http://download.kde.org/stable/${pkgname}/${pkgver}/src/${pkgname}-${pkgver}.tar.xz")
sha1sums=('90741721f68a02d4345b9006a8ae53bc49ef3777')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
  
  # Remove a bunch of symlinks pointing to non-existant files
  for lang in pt_BR uk sv et de en nl; do
     rm  "${pkgdir}"/usr/share/doc/kde/html/${lang}/konversation/common
  done
}