# $Id: PKGBUILD 117421 2011-04-01 18:27:40Z ibiru $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
pkgname=libva
pkgver=1.0.12
pkgrel=1
pkgdesc="Video Acceleration (VA) API for Linux"
arch=('i686' 'x86_64')
url="http://freedesktop.org/wiki/Software/vaapi"
license=('MIT')
depends=('libgl' 'libdrm>=2.4.23' 'libxfixes')
makedepends=('mesa')
optdepends=('vdpau-video: VDPAU backend for VA API')
options=('!libtool')
source=(http://cgit.freedesktop.org/libva/snapshot/${pkgname}-${pkgver}.tar.bz2
        libva-dont-install-tests.patch)
md5sums=('84408a0746a63b8cf308dc7b9f2451cf'
         '0a9bd14c36545c0e9819dfe32ea80f41')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  patch -Np0 -i "${srcdir}/libva-dont-install-tests.patch"
  ./autogen.sh
  ./configure --prefix=/usr  \
    --enable-i965-driver \
    --enable-glx
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -m644 -D COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}

# vim:set ts=2 sw=2 et: