# $Id: PKGBUILD 135632 2011-08-16 21:19:30Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=libvpx
pkgver=0.9.7.p1
realver=0.9.7-p1
pkgrel=1
pkgdesc="The VP8 Codec SDK"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.webmproject.org/"
license=('BSD')
depends=('glibc')
makedepends=('yasm')
source=(http://webm.googlecode.com/files/${pkgname}-v${realver}.tar.bz2
        mips64el.patch)
sha1sums=('dacfefaf3363f781de43858f09cdd0b0d469e6fc'
          '4fd775826a4d737102f831c451235a58947f2cde')

build() {
    cd "${srcdir}/${pkgname}-v${realver}"

    if [ "$CARCH" = "mips64el" ]; then
      extra="--target=mips64el-linux-gcc"
      patch -Np1 -i ${srcdir}/mips64el.patch
    fi

    ./configure --prefix=/usr --enable-vp8 \
        --enable-runtime-cpu-detect \
        --enable-shared \
        --enable-postproc \
        --enable-pic \
        --disable-install-docs \
        --disable-install-srcs $extra
    make
}

package() {
    cd "${srcdir}/${pkgname}-v${realver}"
    make DIST_DIR="$pkgdir/usr" install
    install -D -m 0644 LICENSE "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}