# $Id: PKGBUILD 188841 2013-06-22 12:22:10Z lcarlier $
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=libxi
pkgver=1.7.1
pkgrel=2
pkgdesc="X11 Input extension library"
arch=('i686' 'x86_64')
url="http://xorg.freedesktop.org"
depends=('libxext' 'inputproto')
makedepends=('pkgconfig' 'xorg-util-macros' 'libxfixes' 'automake')
options=(!libtool)
license=('custom')
source=(${url}/releases/individual/lib/libXi-${pkgver}.tar.bz2
        git-fixes.diff)
sha256sums=('e92adb6b69c53c51e05c1e65db97e23751b935a693000fb0606c11b88c0066c5'
            '23e10f8a8a078dd109acbd5a66fe62a45233d3a2368649d5114107a790594c07')

prepare() {
  cd "${srcdir}/libXi-${pkgver}"

  # fix CVE-2013-1998 CVE-2013-1984 CVE-2013-1995 merged upstream
  patch -Np1 -i ${srcdir}/git-fixes.diff

  # a patch change configure.ac
  autoreconf -fiv
}

build() {
  cd "${srcdir}/libXi-${pkgver}"

  ./configure --prefix=/usr --sysconfdir=/etc --disable-static
  make
}

package() {
  cd "${srcdir}/libXi-${pkgver}"

  make DESTDIR="${pkgdir}" install

  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}