# $Id: PKGBUILD 144603 2011-12-07 21:23:41Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Gilles CHAUVIN <gcnweb@gmail.com>

pkgname=live-media
pkgver=2011.12.02
pkgrel=1
pkgdesc="A set of C++ libraries for multimedia streaming"
arch=('i686' 'x86_64' 'mips64el')
license=('LGPL')
url="http://live555.com/liveMedia"
depends=('gcc-libs')
source=("http://live555.com/liveMedia/public/live.${pkgver}.tar.gz")
md5sums=('4f10d93d33f6714a980fd1655ead69cd')

build() {
  cd ${srcdir}/live

   sed \
       -e 's/$(INCLUDES) -I. -O2 -DSOCKLEN_T/$(INCLUDES) -I. '"${CFLAGS}"' -fPIC -DSOCKLEN_T/g' \
       -e 's/\(LIBRARY_LINK =\).*/\1 $(LD) '"${LDFLAGS}"' -o/g' \
       -e 's/\(LIBRARY_LINK_OPTS =\).*/\1 $(LINK_OPTS) -r -Bstatic/g' \
       -i config.linux
  ./genMakefiles linux
  make
}

package() {
  cd ${srcdir}/live

  for dir in BasicUsageEnvironment UsageEnvironment groupsock liveMedia; do
    mkdir -p ${pkgdir}/usr/lib/live/${dir}
    cp -r ${dir}/*.a ${dir}/include ${pkgdir}/usr/lib/live/${dir}
  done

  mkdir -p ${pkgdir}/usr/bin
  for testprog in `find testProgs -type f -perm 755`; do
    install ${testprog} ${pkgdir}/usr/bin
  done
}