# $Id: PKGBUILD 170056 2012-10-31 10:19:33Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=metacity
pkgver=2.34.13
pkgrel=1.1
pkgdesc="A window manager for GNOME"
arch=(i686 x86_64 'mips64el')
license=('GPL')
depends=('dconf' 'gtk2' 'gsettings-desktop-schemas' 'libcanberra'  'libgtop' 'libsm' 'startup-notification' 'zenity')
makedepends=('intltool' 'yelp-tools')
url="http://www.gnome.org"
groups=('gnome')
options=('!libtool' '!emptydirs')
install=metacity.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        fix_compositing_startup.patch)
sha256sums=('8cf4dbf0da0a6f36357ce7db7f829ec685908a7792453c662fb8184572b91075'
            '5094a0ffe3eb8289ed752829877c2e1b743eddf938ad3fc92fb4574b42765ae2')

build() {
  cd "$pkgname-$pkgver"
  patch -Np1 -i "${srcdir}/fix_compositing_startup.patch"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --libexecdir=/usr/lib/metacity \
      --localstatedir=/var --disable-static \
      --disable-schemas-compile
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}