# $Id: PKGBUILD 107236 2011-01-22 19:02:29Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>

pkgname=miro
pkgver=3.5.1
pkgrel=1
pkgdesc="The free and open source internet TV platform"
arch=('i686' 'x86_64')
url="http://www.getmiro.com"
license=('GPL2')
depends=('dbus-python' 'pyrex' 'pygtk' 'gstreamer0.10' 'python2-gconf'
         'python-pysqlite' 'pywebkitgtk' 'shared-mime-info'
         'desktop-file-utils' 'gstreamer0.10' 'hicolor-icon-theme'
         'gstreamer0.10-python' 'python-notify' 'libtorrent-rasterbar'
	 'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'python-pycurl')
makedepends=('pkgconfig')
install=miro.install
source=(http://ftp.osuosl.org/pub/pculture.org/${pkgname}/src/${pkgname}-${pkgver}.tar.gz)
sha1sums=('0f5c2a307e7040c9c2895ee9a2d1c3ff99d34e9e')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/linux"

  python2 setup.py install --root=${pkgdir}

  # fix miro startup script so --debug works with python2
  sed -i "s|which python|which python2|" ${pkgdir}/usr/bin/miro
  sed -i "s|./miro.real|/usr/bin/miro.real|" ${pkgdir}/usr/bin/miro
}