# $Id: PKGBUILD 165621 2012-08-27 12:25:05Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=modemmanager
_realname=ModemManager
pkgver=0.5.2.0
pkgrel=4
pkgdesc="Mobile broadband modem management service"
arch=('i686' 'x86_64')
url="http://cgit.freedesktop.org/ModemManager/ModemManager/"
license=('GPL2')
depends=('dbus-glib' 'udev' 'ppp')
makedepends=('intltool')
optdepends=('usb_modeswitch: install if your modem shows up as a storage drive')
options=('!libtool')
source=(http://download.gnome.org/sources/$_realname/0.5/$_realname-$pkgver.tar.xz
        modem-manager.service)
sha256sums=('7f8b3e1996a24e031df7534e226a0f0c7c2dd8b30322e6c5f4611dc1a848e6c8'
            '118e36f2f956d719cf4036f3fd5f5bf0fde88ca55bdf7ed95051b5b09066fcbe')

build() {
  cd "$_realname-$pkgver"
   ./configure --prefix=/usr \
   	--sysconfdir=/etc \
	--localstatedir=/var \
	--with-udev-base-dir=/usr/lib/udev \
	--disable-static
  make
}

package() {
  cd "$_realname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/modem-manager.service" \
    "$pkgdir/usr/lib/systemd/system/modem-manager.service"
  echo "SystemdService=modem-manager.service" \
    >> "$pkgdir/usr/share/dbus-1/system-services/org.freedesktop.ModemManager.service"
}