# $Id: PKGBUILD 189932 2013-07-11 19:04:39Z ioni $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>

pkgbase=mtr
pkgname=(mtr mtr-gtk)
pkgver=0.85
pkgrel=1
arch=('i686' 'x86_64')
license=('GPL')
makedepends=('ncurses' 'gtk2')
source=(ftp://ftp.bitwizard.nl/mtr/$pkgbase-$pkgver.tar.gz)
url=""ba1e111d270178eb1d65e51ebf6503f
md5sums=('aba1e111d270178eb1d65e51ebf6503f')

build() {
    cp -r  $pkgbase-$pkgver $pkgbase-cli
    cd mtr-cli
    ./configure --prefix=/usr --without-gtk --sbindir=/usr/bin
    make

    cd "$srcdir/$pkgbase-$pkgver"
    ./configure --prefix=/usr --sbindir=/usr/bin
    make
}

package_mtr() {
    pkgdesc="Combines the functionality of traceroute and ping into one tool (CLI version)"
    depends=('ncurses' 'glib2')
    cd mtr-cli
    make DESTDIR="$pkgdir" install
}

package_mtr-gtk() {
    pkgdesc="Combines the functionality of traceroute and ping into one tool (GTK version)"
    depends=('ncurses' "gtk2")
    conflicts=("mtr")
    provides=("mtr=$pkgver")

    cd $pkgbase-$pkgver
    make DESTDIR="$pkgdir" install
}