# $Id: PKGBUILD 178526 2013-02-25 10:11:55Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=nepomuk-core
pkgver=4.10.0
pkgrel=4
pkgdesc="Contains the central Nepomuk services like file indexing, file system monitoring, query, storage, client libraries"
url="https://projects.kde.org/projects/kde/kdelibs/nepomuk-core"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('kdelibs' 'poppler-qt' 'taglib' 'ffmpeg')
makedepends=('cmake' 'automoc4' 'doxygen')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgname}-${pkgver}.tar.xz"
        'fix-recursive-indexing.patch'
        'fix-crash-on-new-install.patch')
sha1sums=('affc4d3063db773e5b05ff746a4c64adbec29264'
          'faa0f661fe642af01ac72eda7347dfc659e091e1'
          '5e3b84f0d0f8a868d4aafedf0f3c7ab631ee4263')

build() {
  cd ${pkgname}-${pkgver}
  patch -p1 -i "${srcdir}"/fix-recursive-indexing.patch
  patch -p1 -i "${srcdir}"/fix-crash-on-new-install.patch
  cd ../

  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install

  # Fix the python shebang
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
    "${pkgdir}"/usr/bin/nepomuk-simpleresource-rcgen
}