# $Id: PKGBUILD 184181 2013-05-03 08:14:17Z foutrelis $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Arjan Timmerman <arjan@archlinux.org>
# Contributor: Wael Nasreddine <gandalf@siemens-mobiles.org>
# Contributor: Tor Krill <tor@krill.nu>
# Contributor: Will Rea <sillywilly@gmail.com>

pkgname=network-manager-applet
pkgver=0.9.8.0
pkgrel=3
pkgdesc="GNOME frontends to NetWorkmanager"
arch=('i686' 'x86_64' 'mips64el')
license=(GPL)
url="http://www.gnome.org/projects/NetworkManager/"
depends=("networkmanager>=${pkgver::5}" libgnome-keyring gtk3 libnotify
         gnome-icon-theme mobile-broadband-provider-info iso-codes)
makedepends=(intltool gnome-bluetooth gobject-introspection)
optdepends=('gnome-bluetooth: for PAN/DUN support')
options=('!libtool' '!emptydirs')
install=network-manager-applet.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/0.9/$pkgname-$pkgver.tar.xz
        fixed-signal-icons.tar.xz)
noextract=(fixed-signal-icons.tar.xz)
sha256sums=('1afb6e736870ba95132bf0d211c46849e02a820ba3902a059a616be888053590'
            '08ffd9d045c98119eb1991c036f41e51950e72eea5638549075239256c000e91')

prepare() {
  cd ${pkgname}-${pkgver}

  # Fix signal icons to work with libpng 1.6
  # https://bugzilla.gnome.org/show_bug.cgi?id=697286
  tar xf ${srcdir}/fixed-signal-icons.tar.xz
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var \
      --libexecdir=/usr/lib/networkmanager \
      --disable-static \
      --disable-maintainer-mode \
      --disable-migration
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}