# $Id: PKGBUILD 158725 2012-05-08 12:53:46Z tomegun $
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Thomas Bächler <thomas.archlinux.org>

pkgbase=ntfs-3g_ntfsprogs
pkgname=('ntfs-3g' 'ntfsprogs')
pkgver=2012.1.15
pkgrel=3
url="http://www.tuxera.com"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('glibc' 'fuse')
makedepends=('pkgconfig')
options=('!libtool')
source=(http://tuxera.com/opensource/$pkgbase-$pkgver.tgz)
sha1sums=('8d55cf49afde172fefa369a0a85289e09c4d7bbb')

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  ac_cv_path_LDCONFIG=/bin/true ./configure --prefix=/usr \
    --with-fuse=external --disable-static \
    --enable-posix-acls --mandir=/usr/share/man
  make
}

package_ntfs-3g() {
  pkgdesc="Stable read and write NTFS driver"

  for DIR in src libntfs-3g include; do
    cd "$srcdir/$pkgbase-$pkgver/$DIR"
    make DESTDIR="$pkgdir" install
  done

  mv "$pkgdir"/lib/* "$pkgdir"/usr/lib/
  mv "$pkgdir"/bin/* "$pkgdir"/usr/bin/
  rm -rf "$pkgdir"/{lib,{s,}bin}

  cd "$pkgdir"/usr/bin
  ln -s ntfs-3g mount.ntfs
  ln -s ntfs-3g mount.ntfs-3g
  ln -s lowntfs-3g mount.lowntfs-3g
}

package_ntfsprogs() {
  pkgdesc="NTFS filesystem utilities"
  depends=('util-linux' 'ntfs-3g')

  cd "$srcdir/$pkgbase-$pkgver/ntfsprogs"
  make DESTDIR="$pkgdir" install

  mv "$pkgdir"/sbin/* "$pkgdir"/usr/bin/
  rm -rf "$pkgdir"/sbin
}