# $Id: PKGBUILD 131039 2011-07-09 20:49:15Z stephane $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor : shining <shiningxc.at.gmail.com>
# Contributor : cyberdune <cyberdune@gmail.com>

pkgname=octave
pkgver=3.4.2
pkgrel=1
pkgdesc="A high-level language, primarily intended for numerical computations."
arch=('i686' 'x86_64' 'mips64el')
url="http://www.octave.org"
license=('GPL')
depends=('fftw' 'pcre' 'curl' 'lapack' 'libx11' 'graphicsmagick' 'glpk' 'hdf5' 'gcc-libs' 'qhull')
makedepends=('texinfo' 'graphicsmagick' 'gcc-fortran' 'umfpack')
optdepends=('texinfo: for help-support in octave'
            'gnuplot: alternative plotting'
	    'umfpack: LU decomposition of some large sparse matrices')
source=("ftp://ftp.gnu.org/gnu/octave/octave-$pkgver.tar.bz2")
options=('!emptydirs')
#install=octave.install
sha1sums=('12cac29ef7d1ab8374980e1e2fd14637b2f15ba5')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # http://www.nabble.com/Random-rounding-errors-td16010966.html
  FFLAGS="-O -ffloat-store" \

  # Avoid build failure due to missing curl/types.h
  sed -i "/curl\/types.h/d" src/DLD-FUNCTIONS/urlwrite.cc

  ./configure --prefix=/usr --libexecdir=/usr/lib \
  --enable-shared --disable-static --disable-docs 

  make
}

package(){
  cd ${srcdir}/${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install

  # add octave library path to ld.so.conf.d
  install -d ${pkgdir}/etc/ld.so.conf.d
  echo "/usr/lib/${pkgname}-${pkgver}" > ${pkgdir}/etc/ld.so.conf.d/${pkgname}.conf
}