# $Id: PKGBUILD 184418 2013-05-06 19:39:04Z foutrelis $
# Maintainer: François Charette <francois ατ archlinux δοτ org>
# Contributor: Jason Chu <jchu@xentac.net>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>

pkgname=perl-tk
_cpanname=Tk
pkgver=804.030
pkgrel=4
pkgdesc="A graphical user interface toolkit for Perl"
arch=('i686' 'x86_64' 'mips64el')
url="http://search.cpan.org/dist/${_cpanname}"
license=('PerlArtistic' 'GPL' 'custom')
depends=('libpng' 'libjpeg' 'tk' 'perl')
options=('!emptydirs')
replaces=('perltk')
provides=('perltk')
source=(http://www.cpan.org/authors/id/S/SR/SREZIC/${_cpanname}-${pkgver}.tar.gz)
md5sums=('13275e85f99ee467a86d9598a437abff')

build() {
  cd "$srcdir/${_cpanname}-$pkgver"
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

#check() {
#  cd "$srcdir/${_cpanname}-$pkgver"
#  make test
#}

package() {
  cd "$srcdir/${_cpanname}-$pkgver"
  make install DESTDIR="$pkgdir"

  # license
  install -D -m644 pTk/license.terms \
                   "${pkgdir}/usr/share/licenses/${pkgname}/tk.license"
  install -D -m644 pTk/Tix.license \
                   "${pkgdir}/usr/share/licenses/${pkgname}/tix.license"
}