# $Id: PKGBUILD 1214 2009-08-14 01:36:33Z dgriffiths $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=physfs
pkgver=2.0.2
pkgrel=2
pkgdesc="A library to provide abstract access to various archives"
arch=('i686' 'x86_64' 'mips64el')
url="http://icculus.org/physfs/"
license=('ZLIB')
depends=('zlib')
makedepends=('cmake' 'doxygen')
options=('!makeflags')
source=(http://icculus.org/physfs/downloads/${pkgname}-${pkgver}.tar.gz)
sha1sums=('2d3d3cc819ad26542d34451f44050b85635344d0')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's/-Werror//' CMakeLists.txt
  export CFLAGS="$CFLAGS -fno-strict-aliasing"
  export CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
  cmake . -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPHYSFS_BUILD_TEST=OFF -DPHYSFS_BUILD_WX_TEST=OFF
  make all docs
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -d "${pkgdir}"/usr/share/{doc/physfs,man/man3}
  install -m644 docs/html/* "${pkgdir}/usr/share/doc/physfs"
  install -m644 docs/man/man3/* "${pkgdir}/usr/share/man/man3"

  for i in author Deinit description extension Free Init major Malloc minor opaque patch Realloc url ; do
    mv "${pkgdir}/usr/share/man/man3/$i.3" "${pkgdir}/usr/share/man/man3/PHYSFS_$i.3"
  done

  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}