# $Id: PKGBUILD 201242 2013-12-06 15:41:36Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>

pkgname=postgresql-old-upgrade
pkgver=9.2.6
_majorver=${pkgver%.*}
pkgrel=1
pkgdesc="PostgreSQL build for migrating between major versions with pg_upgrade"
arch=('i686' 'x86_64')
url="http://www.postgresql.org/"
license=('custom:PostgreSQL')
depends=("postgresql-libs>=${_majorver}" 'libxml2' 'openssl>=1.0.0')
makedepends=('krb5' 'python2' 'perl' 'tcl>=8.6.0')
source=(http://ftp.postgresql.org/pub/source/v${pkgver}/postgresql-${pkgver}.tar.bz2)

build() {
  cd "${srcdir}/postgresql-${pkgver}"

  ./configure --prefix=/opt/pgsql-${_majorver} \
  --with-krb5 \
  --with-libxml \
  --with-openssl \
  --with-perl \
  --with-python PYTHON=/usr/bin/python2 \
  --with-tcl \
  --with-pam \
  --without-readline \
  --with-system-tzdata=/usr/share/zoneinfo \
  --disable-nls \
  --enable-thread-safety

  make -C src all
  make -C contrib all
}

package() {
  cd "${srcdir}/postgresql-${pkgver}"

  # install
  make -C src DESTDIR="${pkgdir}" install
  make -C contrib DESTDIR="${pkgdir}" install

  # install license
  install -D -m644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  # clean up unneeded installed items
  rm -rf "${pkgdir}/opt/pgsql-${_majorver}/include/"
}

md5sums=('3e68c0c7468c56f73060a88a377dbde8')
sha256sums=('4ba98053a66e5678af93dbc2956e8b04623f759e174f48940c41f4251cf0f886')