# $Id: PKGBUILD 148892 2012-02-05 11:54:30Z ibiru $
# Maintainer: Angel Velasquez <angvp@archlinux.org> 
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: john(?)
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=python-pygame
pkgver=1.9.1
pkgrel=4
pkgdesc="Python game library"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.pygame.org/"
license=('LGPL')
depends=('sdl_mixer' 'libvorbis' 'sdl_ttf' 'sdl_image' 'smpeg')
makedepends=('python2' 'portmidi') 
replaces=('pygame')
provides=('pygame')
changelog=ChangeLog
source=(http://pygame.org/ftp/pygame-${pkgver}release.tar.gz 'config.patch'
'pygame-v4l.patch')
md5sums=('1c4cdc708d17c8250a2d78ef997222fc'
         'aaa668f3cd710d8604114501ea6a6f48'
         '9915b63865c16519e80007909beed876')

build() {
	cd "${srcdir}/pygame-${pkgver}release"
	patch -Np0 -i "${srcdir}/config.patch"
    patch -Np1 -i "${srcdir}/pygame-v4l.patch"
}

package() {
	cd "${srcdir}/pygame-${pkgver}release"
	python2 config.py -auto
	python2 setup.py install --root="${pkgdir}" --prefix=/usr
	# Copying the examples and tests
	cp -R examples lib/* "${pkgdir}/usr/lib/python2.7/site-packages/pygame"
	cp -R test/* "${pkgdir}/usr/lib/python2.7/site-packages/pygame/tests"
	# Fixing permissions
	chmod 644 "${pkgdir}"/usr/include/python2.7/pygame/*
}