# $Id: PKGBUILD 178985 2013-03-01 10:24:14Z andrea $
# Maintainer: Ronald van Haren <ronald.archlinux.org>

pkgname=qt-assistant-compat
pkgver=4.6.3
pkgrel=3
pkgdesc="compat version of Qt Assistant"
url="http://qt-project.org/"
arch=('i686' 'x86_64')
license=('GPL3' 'LGPL')
depends=('qt4')
source=('ftp://ftp.qt.nokia.com/qt/source/qt-assistant-qassistantclient-library-compat-src-4.6.3.tar.gz'
        'debian_patches_01_build_system.diff')
md5sums=('a20148e0488d5c12ab35ccc107dcc64d'
         '1b55290dc9fab0c035797e9301d2fa61')

# separate package function does not really work here due to broken build files
build() {
    . /etc/profile.d/qt4.sh

	cd ${srcdir}/qt-assistant-qassistantclient-library-compat-version-${pkgver}

	patch -Np1 -i ${srcdir}/debian_patches_01_build_system.diff

	cd lib; if [ -e Makefile ]; then $(MAKE) distclean; fi
	rm -f translations/assistant_adp_*.qm

	qmake CONFIG+=create_prl
	make
	cd  ../translations; lrelease assistant_adp_*.ts
	cd ..
	qmake CONFIG+=create_prl
	make
}

package() {
	cd ${srcdir}/qt-assistant-qassistantclient-library-compat-version-${pkgver}

	make install INSTALL_ROOT=${pkgdir}
	cd lib
	make install INSTALL_ROOT=${pkgdir}
	cd ..

	# Fix wrong path in prl file
	sed -i -e "/^QMAKE_PRL_BUILD_DIR/d" \
		${pkgdir}/usr/lib/libQtAssistantClient.prl

	# Install translations
	install -d ${pkgdir}/usr/share/qt/translations/
	install -p -m0644 translations/assistant_adp_*.qm \
		${pkgdir}/usr/share/qt/translations/

	# Install prf file
	install -D -p -m0644 features/assistant.prf \
		${pkgdir}/usr/share/qt/mkspecs/features/assistant.prf
}