# $Id: PKGBUILD 131207 2011-07-11 21:16:26Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: damir <damir.archlinux.org>
# Contributor: Gergely Imreh <imrehg@gmail.com>

pkgname=qtiplot
pkgver=0.9.8.6
pkgrel=1
arch=('i686' 'x86_64')
url="http://soft.proindependent.com/qtiplot.html"
pkgdesc="Data analysis and scientific plotting - free clone of Origin"
depends=('muparser' 'gsl' 'python2-qt' 'boost-libs' 'shared-mime-info' 'mesa' 'liborigin2' 'qt-assistant-compat' 'tamu-anova')
# build against qwtplot3d provided in the package ...
# build against qwt provided in the package ...
# as systemwide one doesn't provide all needed functions
makedepends=('pkg-config' 'boost')
license=('GPL2')
install=${pkgname}.install
source=(http://download.berlios.de/qtiplot/qtiplot-${pkgver}.tar.bz2
        $pkgname.desktop
        $pkgname.png
        build.conf.archlinux
        qwtplot3d_gcc.patch
        qtiplot.xml
	qtiplot-0.9.8.6-gold.patch
	qtiplot-0.9.8.6-kde.patch
	qtiplot-0.9.8.6-tamuanova.patch)
sha1sums=('e8a5ea1e1fb0e87cf76985f63b25e263b03f5fa9'
          '4d5d7cf3965a0a1b1aa9cafc34e70ee207700bc8'
          '4301cb2a36024a10108b689990d28c4fe5c7416e'
          'b3af6c866b3e63b537b418b6d00e57ef468f8f2b'
          '301bf6f70e8c1bb9ffd55eb49eedde7b29a12909'
          '285f57d865956d93250ec548288c5bface096b6b'
          'b534a609f317cf3117d6495909854cdacea20124'
          'a1d4bec744c9b8fe29bf177851e66c97cdd9d975'
          '830b518e3ef63625df84363a8047417124f243b0')


build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

   # gentoo fixes  
   patch -Np1 -i "${srcdir}/qtiplot-0.9.8.6-gold.patch"
   patch -Np1 -i "${srcdir}/qtiplot-0.9.8.6-kde.patch"
   patch -Np1 -i "${srcdir}/qtiplot-0.9.8.6-tamuanova.patch"

   # build also static qwtplot3d lib
   echo "unix:CONFIG += staticlib" >> 3rdparty/qwtplot3d/qwtplot3d.pro

  # install build configuration file
  install -Dm644 "${srcdir}/build.conf.archlinux" build.conf

  # Make qwt
  sed -i "s:elif:else:g" qtiplot/src/scripting/ScriptEdit.cpp
  patch -Np1 -i "${srcdir}/qwtplot3d_gcc.patch"
  cd ./3rdparty/qwt
  qmake
  make

  # Make qwtplot3d
  cd ../qwtplot3d
  qmake
  make

  # Make qtiplot
  cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"

  # fix stuff
  sed -i 's|/usr/local/|/usr/share/|' qtiplot.pro
  sed -i 's|<QAssistantClient>|<QtAssistant/qassistantclient.h>|' src/core/ApplicationWindow.cpp
  sed -i 's#d_python_config_folder + "#"/usr/share/qtiplot#' src/core/ApplicationWindow.cpp

  qmake qtiplot.pro QMAKESPEC=linux-g++
  make QTDIR=/usr/ QMAKESPEC=linux-g++
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/${pkgname}"

  INSTALL_ROOT="${pkgdir}" make install

  # make it nice:
  install -D -m644 "${srcdir}/${pkgname}.png" \
  	"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  install -D -m644 "${srcdir}/${pkgname}.desktop" \
  	"${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -D -m644 "${srcdir}/${pkgname}.xml" \
        "${pkgdir}/usr/share/mime/packages/${pkgname}.xml"
}