# $Id: PKGBUILD 135654 2011-08-17 02:18:35Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=racket
pkgver=5.1.3
pkgrel=1
pkgdesc="A programming language environment (formerly known as PLT Scheme) suitable for tasks ranging from scripting to application development"
arch=('i686' 'x86_64' 'mips64el')
url="http://racket-lang.org/"
license=('LGPL')
depends=('gtk2' 'libffi' 'desktop-file-utils')
makedepends=('gsfonts')
options=('!strip')
install=racket.install
source=(http://download.racket-lang.org/installers/${pkgver}/racket/${pkgname}-${pkgver}-src-unix.tgz \
        drracket.desktop)
md5sums=('6c33caf6ee49a422be053effaf630941'
         '9223c9736ead677431542b41271c7b3c')
sha1sums=('7face74729cee8b36ce3df44b36b04ca23b4c986'
          'a20808f6b250225704856f82a544681a962a299d')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../collects/icons/plt.xpm "${pkgdir}/usr/share/pixmaps/drracket.xpm"
  install -D -m644 "${srcdir}/drracket.desktop" "${pkgdir}/usr/share/applications/drracket.desktop"
}