# $Id: PKGBUILD 156964 2012-04-23 09:10:10Z ibiru $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>

pkgname=seahorse
pkgver=3.4.1
pkgrel=1
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64 'mips64el')
license=('GPL')
url="http://projects.gnome.org/seahorse/"
depends=('gtk3' 'gcr' 'libgnome-keyring' 'libsoup' 'gpgme' 'desktop-file-utils' 'hicolor-icon-theme' 'dconf')
makedepends=('libldap' 'intltool' 'gnome-doc-utils' 'gobject-introspection' 'openssh' 'libsm')
optdepends=('openssh: SSH support')
provides=('x11-ssh-askpass')
options=('!libtool' '!emptydirs')
groups=('gnome-extra')
install=seahorse.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        seahorse-ssh-askpass.sh
        10_gpgme_keyring_finalize_typo.patch)
sha256sums=('841443ed6d7f865e1c9347867527591287bcc5b2e281c8da11b2cb355d678faa'
            '400ea9a6084acc93f1dbd4223b95622bbd48071b763063328efba00de378b68c'
            '5bdbe26d89dc256923cd26601a5639e5596ed488a2294618c1754d96de5f7d1c')

build() {
  cd "$pkgname-$pkgver"

  # From Debian.
  patch -p1 -i "$srcdir/10_gpgme_keyring_finalize_typo.patch"

  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static \
      --enable-ldap --enable-hkp \
      --disable-schemas-compile
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm755 "$srcdir/seahorse-ssh-askpass.sh" \
    "$pkgdir/etc/profile.d/seahorse-ssh-askpass.sh"
}