# $Id: PKGBUILD 124485 2011-05-22 15:13:07Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>

pkgname=seahorse
pkgver=3.0.2
pkgrel=1
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64 'mips64el')
license=('GPL')
url="http://projects.gnome.org/seahorse/"
depends=('gtk3' 'gconf' 'libgnome-keyring' 'gnome-keyring' 'libnotify' 'libsoup' 'gpgme' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('gettext' 'libldap' 'intltool' 'pkgconfig' 'gnome-doc-utils' 'gobject-introspection' 'openssh' 'libsm')
options=('!libtool' '!emptydirs')
groups=('gnome-extra')
install=seahorse.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
sha256sums=('78b38d6e7220d1957af34eac79c21423f1f4be066853126d30cc030d8407a1bf')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static \
      --enable-ldap --enable-hkp \
      --disable-scrollkeeper \
      --disable-update-mime-database
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install

  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain seahorse ${pkgdir}/etc/gconf/schemas/*.schemas
  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
}