# $Id: PKGBUILD 136036 2011-08-21 23:32:17Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=soundtouch
pkgver=1.6.0
pkgrel=1
pkgdesc="An audio processing library"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.surina.net/soundtouch/"
license=('LGPL')
depends=('gcc-libs')
options=('!libtool')
source=(http://www.surina.net/soundtouch/${pkgname}-${pkgver}.tar.gz
        soundtouch-1.4.0-mmx-sse-compile-fix.patch
        soundtouch-1.4.0-x86_64-asm-broken.patch
        disable-mmx.patch)
md5sums=('aa1c63d4d67b033f044a6a48d2be5bdd'
         '108cd080b4b0ebe8ed1f950ff1315e7a'
         '0d856bb5b519b18c6ba3a2e1770bdfd2'
         '36e859e7a74a21ec7f9a5282fed63117')

build() {
  cd "${srcdir}/${pkgname}"
  patch -p1 -i "${srcdir}/soundtouch-1.4.0-mmx-sse-compile-fix.patch"
  patch -p1 -i "${srcdir}/soundtouch-1.4.0-x86_64-asm-broken.patch"
  [ "${CARCH}" = "mips64el" ] && patch -p1 -i "${srcdir}/disable-mmx.patch"

  ./bootstrap
  case $CARCH in
    i686)
      ./configure --prefix=/usr --enable-shared
      ;;
    *)
      ./configure --prefix=/usr --enable-shared --with-pic
      ;;
  esac
  make
}

package() {
  cd "${srcdir}/${pkgname}"
  make DESTDIR="${pkgdir}" pkgdocdir=/usr/share/doc/soundtouch install
}