# $Id: PKGBUILD 106155 2011-01-14 21:07:17Z bisson $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: Neil Lin <neil@vip.url.com.tw>

pkgname=stardict
pkgver=3.0.2
pkgrel=2
pkgdesc='A powerful international dictionary written in Gtk2.'
arch=('i686' 'x86_64')
url='http://stardict.sourceforge.net/'
license=('GPL')
depends=('enchant' 'gtk2' 'libsigc++' 'libsm')
makedepends=('intltool' 'popt' 'gnome-doc-utils')
options=('!libtool' '!emptydirs')
source=("http://downloads.sourceforge.net/sourceforge/stardict/$pkgname-$pkgver.tar.bz2"
        'help-in-destdir.patch'
        'as-needed.patch')
sha1sums=('301875657cd39b5f25e5933ece22936a28db1230'
          '0249d769e5cc85e183eb395b824342f8ca320f56'
          '22fca061d1be23ac79da6c0ec5fc488ae0aca9c1')

build()
{
	cd "$srcdir/$pkgname-$pkgver"

	# patches accepted upstream; will be in stardict>3.0.2
	patch -p1 -i ../help-in-destdir.patch
	patch -p1 -i ../as-needed.patch
	automake

	./configure PKG_CONFIG=/usr/bin/pkg-config --prefix=/usr \
		--sysconfdir=/etc --mandir=/usr/share/man \
		--disable-gnome-support --disable-schemas-install \
		--disable-espeak --disable-gucharmap \
		--disable-festival --disable-updateinfo
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install
}