# $Id: PKGBUILD 179819 2013-03-09 18:32:21Z andrea $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=telepathy-qt
pkgver=0.9.3
pkgrel=6
pkgdesc="A library for Qt-based Telepathy clients"
arch=('i686' 'x86_64' 'mips64el')
url="http://telepathy.freedesktop.org/wiki/"
license=('LGPL')
options=('!libtool')
depends=('qt4')
makedepends=('libxslt' 'python2' 'cmake' 'doxygen' 'telepathy-glib')
conflicts=('telepathy-qt4')
replaces=('telepathy-qt4')
provides=('telepathy-qt4')
source=("http://telepathy.freedesktop.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.asc})
md5sums=('94ac93aedf5f6fff49837bc8368e5a37'
         'e1b851b08b159fca39596ff8395ca53a')

build() {
    mkdir build
    cd build
    cmake ../${pkgname}-${pkgver} \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DPYTHON_EXECUTABLE=/usr/bin/python2 \
        -DENABLE_TESTS=OFF
    make
}

package() {
    cd build
    make DESTDIR="$pkgdir" install
}