# $Id: PKGBUILD 168259 2012-10-07 03:32:14Z eric $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>
# Contributor:  Douglas Soares de Andrade <douglas@archlinux.org>

pkgname=twisted
pkgver=12.2.0
pkgrel=1
pkgdesc="Asynchronous networking framework written in Python."
arch=('i686' 'x86_64' 'mips64el')
url="http://twistedmatrix.com/"
license=('MIT')
depends=('python2-crypto' 'python2-zope-interface')
optdepends=('python2-pyopenssl'
            'python-soappy: for twisted.web.soap'
	    'python2-pyasn1: for using conch'
	    'pygtk: for using manhole'
	    'tk: for using tkconch')
install=twisted.install
source=(http://twistedmatrix.com/Releases/Twisted/${pkgver%.*}/Twisted-$pkgver.tar.bz2)
sha1sums=('c51834c1270e7a4bb0de9190056e4317413920f9')

build() {
    cd "$srcdir/Twisted-$pkgver"
    python2 setup.py build
}

package() {
    cd "$srcdir/Twisted-$pkgver"
    python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
    install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    sed -i 's:^#!.*bin.*python:#!/usr/bin/python2:' \
      "$pkgdir"/usr/lib/python2.7/site-packages/twisted/trial/test/scripttest.py \
      "$pkgdir"/usr/lib/python2.7/site-packages/twisted/mail/test/pop3testserver.py \
      "$pkgdir"/usr/lib/python2.7/site-packages/twisted/python/test/pullpipe.py
}