# $Id: PKGBUILD 149800 2012-02-10 23:21:36Z thomas $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
pkgname=v4l-utils
pkgver=0.8.6
pkgrel=1
pkgdesc="Userspace tools and conversion library for Video 4 Linux"
arch=('i686' 'x86_64')
url="http://freshmeat.net/projects/libv4l"
provides=("libv4l=$pkgver")
replaces=('libv4l')
conflicts=('libv4l')
license=('LGPL')
makedepends=('qt')
optdepends=('qt')
depends=('glibc' 'gcc-libs' 'sysfsutils' 'libjpeg-turbo')
source=(http://linuxtv.org/downloads/v4l-utils/${pkgname}-${pkgver}.tar.bz2
        http://linuxtv.org/downloads/v4l-utils/${pkgname}-${pkgver}.tar.bz2.asc)
sha256sums=('3a53ac6348363bbdc94ea11ca48dadc0342a579384a910f6c956b6a185f0c20f'
            '3c2613c77dd68e94ac9eb2b2e856b94e3d3cea57f5de054b95150cbc905b1f18')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  sed -i 's|CFLAGS :=|CFLAGS ?=|' Make.rules

  make PREFIX="/usr"
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make install PREFIX="/usr" DESTDIR="${pkgdir}/"
  rm -f "${pkgdir}/usr/bin/ivtv-ctl"
}