# $Id: PKGBUILD 142435 2011-11-09 18:50:28Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Massimiliano Torromeo <massimiliano DOT torromeo AT google mail service>

pkgname=virtuoso
pkgver=6.1.4
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='A scalable cross-platform server that combines SQL/RDF/XML Data Management with Web Application Server and Web Services Platform functionality'
url='http://virtuoso.openlinksw.com/wiki/main/Main/'
license=('GPL')
depends=('libldap')
makedepends=('bison' 'flex')
options=('!libtool')
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-opensource-${pkgver}.tar.gz")
md5sums=('7110a0b4b171b84850d346f4fe648172')

build() {
  cd ${srcdir}/${pkgname}-opensource-${pkgver}

  ./configure --prefix=/usr \
    --localstatedir=/var \
    --sysconfdir=/etc \
    --disable-rendezvous \
    --disable-hslookup \
    --disable-all-vads
  make
}

package() {
  # install server
  cd ${srcdir}/${pkgname}-opensource-${pkgver}/binsrc/virtuoso
  make DESTDIR=${pkgdir} install

  # install driver
  cd ${srcdir}/${pkgname}-opensource-${pkgver}/binsrc/driver
  make DESTDIR=${pkgdir} install
}