# $Id: PKGBUILD 198479 2013-10-30 15:06:54Z allan $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=vte
pkgver=0.28.2
pkgrel=3.2
pkgdesc="Virtual Terminal Emulator widget for use with GTK2"
arch=('i686' 'x86_64' 'mips64el')
license=('LGPL')
options=('!emptydirs')
depends=('gtk2' 'vte-common')
makedepends=('pygtk' 'intltool' 'gobject-introspection' 'pygobject2-devel')
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/GNOME/sources/vte/0.28/vte-$pkgver.tar.xz
        make_alt_work.patch)
sha256sums=('86cf0b81aa023fa93ed415653d51c96767f20b2d7334c893caba71e42654b0ae'
            '978c989fb63884289068bcee05a92614a3a2be9e5d9386ab789dfb87163b92c8')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  #warning: type-punning to incomplete type might break strict-aliasing rules
  export CFLAGS="$CFLAGS -fno-strict-aliasing"

  patch -Np1 -R -i "$srcdir/make_alt_work.patch"

  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
      --libexecdir=/usr/lib/vte \
      --localstatedir=/var --disable-static \
      --enable-introspection --with-gtk=2.0
  make
}

package(){
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  rm "$pkgdir/usr/lib/vte/gnome-pty-helper"
}