# $Id: PKGBUILD 145279 2011-12-21 02:07:07Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: Eduard "bekks" Warkentin <eduard.warkentin@gmail.com>
# Contributor: Henning Garus <henning.garus@gmail.com>

pkgname=xdelta3
pkgver=3.0.0
pkgrel=2
pkgdesc="A diff utility which works with binary files"
arch=('i686' 'x86_64')
url="http://xdelta.org/"
license=('GPL')
makedepends=('python2')
optdepends=('python2: for python modules')
source=(http://xdelta.googlecode.com/files/xdelta$pkgver.tar.gz
        xdelta3-makefile.patch)
md5sums=('5fe038be3a266d2a7913e10d1cec6d88'
         'fa5973870faf7523043c4858ab7c3bdb')

build() {
  cd $srcdir/xdelta$pkgver

  patch -Np1 -i $srcdir/xdelta3-makefile.patch
  sed -i "/PYVER = /s/2.6/2.7/" Makefile
  
  make xdelta3
  make xdelta3module.so
  
  # for testsuite
  make xdelta3-debug
}

check() {
  cd $srcdir/xdelta$pkgver

  make test
}

package() {
  cd $srcdir/xdelta$pkgver
  
  install -D xdelta3 $pkgdir/usr/bin/xdelta3
  python2 ./setup.py install --root ${pkgdir}
  install -m644 {xdelta3.py,xdelta3module.so} ${pkgdir}/usr/lib/python2.7/site-packages
}