# $Id: PKGBUILD 155348 2012-04-02 00:26:21Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=xfig
pkgver=3.2.5b
pkgrel=8
pkgdesc="An interactive drawing tool"
arch=('i686' 'x86_64')
url="http://www.xfig.org/userman/"
license=('custom')
depends=('libpng' 'libjpeg' 'libxaw' 'libxi' 'desktop-file-utils' 'gsfonts')
makedepends=('imake')
optdepends=('transfig: to use the frontend to convert fig files')
options=('!makeflags' '!emptydirs')
install=xfig.install
source=(http://downloads.sourceforge.net/mcj/${pkgname}.${pkgver}.full.tar.gz \
	xfig-3.2.4-redhat.patch xfig-3.2.5-color-resources.patch \
        xfig-3.2.5-urwfonts.patch \
        xfig-3.2.5-fhs.patch xfig-3.2.5-missing-protos.patch \
        xfig.3.2.5-modularX.patch xfig-3.2.5b-fix-eps-reading.patch \
        xfig-3.2.5b-libpng-1.5.patch LICENSE xfig.desktop)
sha1sums=('0730d7e6bc217c0de02682efb0078821512bb542'
          '926ad99c7221baa4aa9e9737722958860b2700fc'
          'b7c03fb70066ff476a4039a8c0f8930c15edef68'
          'e595ccdbe293ea0fdecbf59a2192ae57ced2c8eb'
          '39bec6bac9746b643b05fd1286826113ede07ff6'
          'bd76cd50be6a5789cfd6f182309cfd7056be04f3'
          'a1285f4e61ad2eec040460ab03e8022098e7f78e'
          '12a64ddaf65a73e23ef74f31483515a0e262768c'
          '83032eb61c8dc96d5fc509a1ce632528457d4598'
          '31edf4cfab708820ea3f114d095dfef5aa88e5aa'
          '9011b8fa6143e37525b28cc9800a3bf2d6b008d2')

build() {
  cd "${srcdir}/${pkgname}.${pkgver}"
  patch -p1 < ../xfig-3.2.4-redhat.patch
  patch -p1 < ../xfig-3.2.5-fhs.patch
  patch -p1 < ../xfig.3.2.5-modularX.patch
  patch -p1 < ../xfig-3.2.5-color-resources.patch
  patch -p1 < ../xfig-3.2.5-urwfonts.patch
  patch -p1 < ../xfig-3.2.5-missing-protos.patch
  patch -p1 < ../xfig-3.2.5b-fix-eps-reading.patch
  patch -p1 < ../xfig-3.2.5b-libpng-1.5.patch
  sed -i 's/#define XAW3D/XCOMM #define XAW3D/' Imakefile
  chmod 755 Libraries

  xmkmf
  make DOCDIR=/usr/share/doc
}

package() {
  cd "${srcdir}/${pkgname}.${pkgver}"
  make DESTDIR="${pkgdir}" DOCDIR=/usr/share/doc install.all
  rm "${pkgdir}/usr/lib/X11/app-defaults"

  find "${pkgdir}/usr/share/xfig/Libraries" -type f -exec chmod 0644 {} \;
  find "${pkgdir}/usr/share/xfig/Libraries" -type d -exec chmod 0755 {} \;
  find "${pkgdir}/usr/share/doc/xfig" -type f -exec chmod 0644 {} \;
  find "${pkgdir}/usr/share/doc/xfig" -type d -exec chmod 0755 {} \;

  install -D -m644 ../xfig.desktop "${pkgdir}/usr/share/applications/xfig.desktop"
  install -D -m644 xfig.png  "${pkgdir}/usr/share/pixmaps/xfig.png"
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"	
}