# $Id: PKGBUILD 178143 2013-02-16 22:49:01Z ioni $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=xine-lib
pkgver=1.2.2
pkgrel=6
pkgdesc="A multimedia playback engine"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.xine-project.org"
license=('LGPL' 'GPL')
depends=('libxvmc' 'ffmpeg' 'libxinerama')
makedepends=('wavpack' 'faad2' 'libmng' 'imagemagick' 'libmodplug'
             'vcdimager' 'jack' 'aalib' 'libdca' 'a52dec' 'libmad' 
             'libmpcdec' 'libcaca' 'libbluray' 'gnome-vfs')
[ "$CARCH" = "mips64el" ] || makedepends+=('glu' 'libvdpau')
optdepends=('imagemagick: for using the imagemagick plugin' \
            'jack: for using the jack plugin' \
            'vcdimager: for using the vcd plugin')
[ "$CARCH" = "mips64el" ] || optdepends+=('glu: for using the opengl plugin')
optdepends+=('wavpack: for using the wavpack plugin' \
            'faad2: for using the faad plugin' \
            'libmng: for using the mng plugin' \
            'aalib: for using the aalib plugin' \
            'libmodplug: for using the modplug plugin' \
            'libdca: for using the dca plugin' \
            'a52dec: for using the a52 plugin' \
            'libmad: for using the mp3 plugin' \
            'libmpcdec: for using the musepack plugin' \
            'libcaca: for using the caca plugin' \
            'libbluray: for using the bluray plugin' \
            'gnome-vfs: for using the gnome-vfs plugin')
[ "$CARCH" = "mips64el" ] || optdepends+=('libvdpau: for using the VDPAU plugin')
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/xine/${pkgname}-${pkgver}.tar.xz
	0001-fix-non-x86-build.patch)
sha1sums=('a349cbb0b72256bb262377796a022dcf63829b4c'
	  '5f1a34c7bafa7ea96c0e4e14fbf6e31e53fe41e0')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i ${srcdir}/0001-fix-non-x86-build.patch
  [ "$CARCH" = "mips64el" ] || extraconf=--enable-vdpau
  ./configure --prefix=/usr --with-wavpack --disable-optimizations $extraconf
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}