# $Id: PKGBUILD 184215 2013-05-03 22:54:49Z tomegun $
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=ypserv
pkgver=2.31
pkgrel=1
pkgdesc='Linux NIS Server'
arch=('i686' 'x86_64' 'mips64el')
url='http://www.linux-nis.org/nis/ypserv/'
license=('GPL2')
depends=('gdbm' 'openslp' 'inetutils' 'yp-tools')
optdepends=('gawk: for printcap support')
backup=('etc/ypserv.conf' 'etc/netgroup' 'var/yp/securenets')
source=("http://www.linux-nis.org/download/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        'ypxfrd.service'
        'yppasswdd.service'
	'ypserv.service')

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./configure --prefix=/usr
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install

	install -D -m644 etc/netgroup "${pkgdir}"/etc/netgroup
	install -D -m644 etc/ypserv.conf "${pkgdir}"/etc/ypserv.conf
	install -D -m644 etc/securenets "${pkgdir}"/var/yp/securenets
	install -D -m644 ../ypxfrd.service "${pkgdir}"/usr/lib/systemd/system/ypxfrd.service
	install -D -m644 ../ypserv.service "${pkgdir}"/usr/lib/systemd/system/ypserv.service
	install -D -m644 ../yppasswdd.service "${pkgdir}"/usr/lib/systemd/system/yppasswdd.service
}
md5sums=('4537b8f0e917edca8f57b70b9cbc37f3'
         'c80e253756446d59a90c4c21b1cb8740'
         '7cba3dd3544436c3c1f05e36c0018e92'
         '3398271c3e0a054e64b06b99aa2dc63d')