# $Id: PKGBUILD 136946 2011-09-03 11:36:21Z ibiru $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Adam Hani Schakaki <krzd@krzd.net>

pkgname=caribou
pkgver=0.3.5
pkgrel=2
pkgdesc="A text entry and UI navigation application being developed as an alternative to the Gnome On-screen Keyboard."
arch=('i686' 'x86_64')
url="http://live.gnome.org/Caribou"
license=('LGPL')
depends=('pyatspi' 'dbus-python' 'python2-gobject2' 'gtk3' 'libxklavier' 'libgee' 'dconf')
makedepends=('gnome-doc-utils' 'intltool' 'gobject-introspection' 'python2-gobject' 'clutter')
install=caribou.install
options=(!libtool !emptydirs)
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/0.3/$pkgname-$pkgver.tar.xz)
sha256sums=('729aa2e896a434490b9728911a1087013c829f7d41259684518e101abd90a9d4')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i s'|#!/usr/bin/python|#!/usr/bin/python2|'g tools/{fix_gir,make_schema}.py
  export PYTHON=/usr/bin/python2
  ./configure --prefix=/usr --sysconfdir=/etc \
    --libexecdir=/usr/lib/caribou \
    --disable-gtk2-module \
    --disable-static \
    --disable-schemas-compile
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: