# $Id: PKGBUILD 167028 2012-09-24 19:57:00Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=evince
pkgver=3.5.92
pkgrel=1
pkgdesc="Simply a document viewer"
url="http://projects.gnome.org/evince/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gtk3' 'libgxps' 'libspectre' 'gsfonts' 'poppler-glib' 'djvulibre' 'gnome-icon-theme' 't1lib' 'libgnome-keyring' 'desktop-file-utils' 'dconf' 'gsettings-desktop-schemas')
makedepends=('itstool' 'nautilus' 'texlive-bin' 'intltool' 'gobject-introspection' 'docbook-xsl')
optdepends=('texlive-bin: DVI support')
groups=('gnome-extra')
install=evince.install
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('47c5439fa2bac884881e23078d1055c5d8dee7fd93e5142b9d5545a095a166d6')

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr   --sysconfdir=/etc \
      --localstatedir=/var    --libexecdir=/usr/lib/evince \
      --disable-static        --enable-nautilus \
      --enable-pdf            --enable-tiff \
      --enable-djvu           --enable-dvi \
      --enable-t1lib          --enable-comics \
      --disable-scrollkeeper  --disable-schemas-compile \
      --enable-introspection
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}