# $Id: PKGBUILD 138398 2011-09-21 14:27:36Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-session
pkgver=3.1.92
pkgrel=1
pkgdesc="The GNOME Session Handler"
arch=(i686 x86_64)
license=('GPL' 'LGPL')
depends=('upower' 'gtk3' 'gconf' 'json-glib' 'startup-notification' 'hicolor-icon-theme' 'libxtst' 'polkit-gnome' 'libgl' 'gsettings-desktop-schemas' 'consolekit' 'libsm' 'dconf')
makedepends=('intltool' 'mesa' 'xtrans')
options=('!emptydirs')
install=gnome-session.install
url="http://www.gnome.org"
groups=('gnome')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz)
sha256sums=('dc505c6730da6ed984d7f72ad31c9780d4d19d72f673ea60feec2e9f685c33f3')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/gnome-session \
      --disable-schemas-compile
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}