# $Id: PKGBUILD 138090 2011-09-16 08:43:47Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

pkgbase=pygobject
pkgname=(python-gobject python2-gobject pygobject-devel)
pkgver=2.90.4
pkgrel=1
arch=('i686' 'x86_64')
url="https://live.gnome.org/PyGObject"
license=('LGPL')
depends=('glib2' 'gobject-introspection' )
makedepends=(python python2 python-cairo python2-cairo)
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgbase}/${pkgver%.*}/${pkgbase}-${pkgver}.tar.xz)
options=('!libtool')
sha256sums=('8407b6997181bbca4783798e21d7d63ca41708a6c05a3b08c953d64e7b97b2a1')

build() {
  cd "${srcdir}"
  cp -a "${pkgbase}-${pkgver}" python2-build
  mkdir devel

  (
    cd python2-build
    export PYTHON=/usr/bin/python2
    ./configure --prefix=/usr
    make
  )

  (
    cd "${pkgbase}-${pkgver}"
    ./configure --prefix=/usr
    make
  )
}

package_python-gobject() {
  pkgdesc="Python 3 bindings for GObject"
  depends+=('python' 'python-cairo' "pygobject-devel=${pkgver}")

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  rm -r "${pkgdir}"/usr/{include,lib/pkgconfig}
}

package_python2-gobject() {
  pkgdesc="Python 2 bindings for GObject"
  depends+=('python2' 'python2-cairo' "pygobject-devel=${pkgver}")

  cd "${srcdir}/python2-build"
  make DESTDIR="${pkgdir}" install
  mv "${pkgdir}"/usr/{include,lib/pkgconfig} "${srcdir}/devel"
}

package_pygobject-devel() {
  pkgdesc="Development files for the pygobject bindings"
  cd "${srcdir}/devel"
  mkdir -p "${pkgdir}"/usr/{include,lib}
  mv include "${pkgdir}/usr/"
  mv pkgconfig "${pkgdir}/usr/lib/"
}