# $Id: PKGBUILD 161675 2012-06-13 14:09:50Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgbase=kdebindings-python
pkgname=('kdebindings-python'
         'kdebindings-python2')
pkgver=4.8.90
pkgrel=1
url='https://projects.kde.org/projects/kde/kdebindings/pykde4'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kdebindings')
makedepends=('cmake' 'automoc4' 'boost' 'kdepim-runtime' 'python2-pyqt' 'qscintilla')
source=("http://download.kde.org/unstable/${pkgver}/src/pykde4-${pkgver}.tar.xz")
sha1sums=('5e61dc43f78a5127486217120ba6c9f06744232a')

build() {
  export PYTHONDONTWRITEBYTECODE="TRUE"

  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../pykde4-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPYTHON_LIBRARY=/usr/lib/libpython3.2mu.so.1.0 \
    -DWITH_Soprano=OFF
  make
  cd ..

  mkdir build-python2
  cd build-python2
  cmake ../pykde4-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPYTHON_EXECUTABLE=/usr/bin/python2 \
    -DWITH_Soprano=OFF
  make
}

package_kdebindings-python() {
  pkgdesc="A set of Python 3.x bindings for KDE"
  depends=('kdepim-runtime' 'pyqt' 'qscintilla')

  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}

package_kdebindings-python2() {
  pkgdesc="A set of Python 2.x bindings for KDE"
  depends=('kdepim-runtime' 'python2-pyqt' 'qscintilla')
  conflicts=('kdebindings-python<4.8.1-2')
 
  cd "${srcdir}"/build-python2
  make DESTDIR="${pkgdir}" install

  # Fix conflicts
  rm "${pkgdir}"/usr/bin/pykdeuic4
  ln -sf /usr/lib/python2.7/site-packages/PyQt4/uic/pykdeuic4.py \
    "${pkgdir}"/usr/bin/python2-pykdeuic4

  mv "${pkgdir}"/usr/share/apps/pykde4/examples \
    "${pkgdir}"/usr/share/apps/pykde4/python2-examples

  mv "${pkgdir}"/usr/share/sip/PyKDE4 \
    "${pkgdir}"/usr/share/sip/python2-PyKDE4

  # Use the python2 executable
  find "${pkgdir}" -name '*.py' | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
}