# $Id: PKGBUILD 102234 2010-12-06 22:32:25Z ibiru $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Maël Lavault <moimael@neuf.fr>

pkgbase=abiword-libre
pkgname=('abiword-libre' 'abiword-libre-plugins')
pkgver=2.8.6
pkgrel=4
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.abisource.com"
makedepends=('pkgconfig' 'asio' 'boost' 'fribidi' 'goffice' 'libwmf' 'wv'
'link-grammar' 'gtkmathview' 'aiksaurus' 'libxslt' 'enchant' 'libots' 'libwpg'
'librsvg' 'loudmouth' 'libsoup' 'ttf-liberation')
options=('!libtool')
source=("http://repo.parabolagnulinux.org/other/${pkgbase}-${pkgver}.tar.gz"
        liberation-fonts.patch
        compat_libwpg_0_9.patch)
conflicts=('abiword')
replaces=('abiword')
provides=("abiword=$pkgver")


# source PKGBUILD; mksource
mksource() {
  #wget http://www.abisource.com/downloads/abiword/${pkgver}/source/abiword-${pkgver}.tar.gz -O -| \
  #  tar xzf -

  pushd abiword-${pkgver}
  #find -type f -print0 | xargs -0 sed -i "s:Times New Roman:Liberation Serif:g"
  patch -Np1 -i ../liberation-fonts.patch || return 1
  popd

  mv abiword-${pkgver} ${pkgbase}-${pkgver}
  tar czf ${pkgbase}-${pkgver}.tar.gz ${pkgbase}-${pkgver}/

  rm -r ${pkgbase}-${pkgver}/

}

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"

  patch -Np1 -i "${srcdir}/compat_libwpg_0_9.patch"
  libtoolize --force
  autoreconf

  ./configure --prefix=/usr --enable-clipart --enable-templates \
              --enable-collab-backend-xmpp --enable-collab-backend-tcp \
              --enable-collab-backend-service --disable-collab-backend-sugar \
              --enable-plugins --without-gnomevfs --with-gio --with-goffice \
              --disable-static --with-psiconv-config=/nothere 


  sed -ir 's/--no-undefined/-no-undefined/' src/Makefile
  make
}

package_abiword-libre() {
  pkgdesc="A fully-featured word processor that doesn't recommend unfree fonts"
  depends=('fribidi' 'wv' 'goffice' 'librsvg' 'enchant')
  optdepends=('abiword-plugins')
  conflicts=("abiword-plugins<${pkgver}-${pkgrel}")

  cd "${srcdir}/${pkgbase}-${pkgver}"
  sed -i plugins/Makefile \
      -e 's/ collab / /' \
      -e 's/ wpg / /' \
      -e 's/ wmf / /' \
      -e 's/ grammar / /' \
      -e 's/ mathview / /' \
      -e 's/ aiksaurus / /' \
      -e 's/ latex / /' \
      -e 's/ ots / /' \
      -e 's/ wordperfect / /'
  make DESTDIR="${pkgdir}" install
}

package_abiword-libre-plugins() {
  pkgdesc="Additional plugins for Abiword"
  depends=("abiword-libre=${pkgver}-${pkgrel}" 'loudmouth' 'libwpg' 'libwmf'
           'link-grammar' 'gtkmathview' 'aiksaurus' 'libxslt' 'libsoup' 'libots')

  cd "${srcdir}/${pkgbase}-${pkgver}/plugins"
  for dir in collab wpg wmf grammar mathview aiksaurus latex ots wordperfect; do
    make -C ${dir} DESTDIR="${pkgdir}" install
  done
}
md5sums=('d0f5d16d9259792fba0a3200c30ff6ae'
         '6dcbf402f58d55cb4a9732348facd236'
         '09446a2ebba8288fc611e88f7cf17298')
md5sums=('d0f5d16d9259792fba0a3200c30ff6ae'
         '880b17db6f249d977d2a7cd012d9ce02'
         '09446a2ebba8288fc611e88f7cf17298')