# $Id: PKGBUILD 46622 2011-05-10 10:00:25Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: jlvsimoes <jlvsimoes@oninet.pt>
# Contributor: kevin <kevin@archlinux.org>

pkgname=abuse-libre
pkgver=0.8
pkgrel=1
pkgdesc='A side-scroller action game that pits you against ruthless alien killers. Without unfree "Claudio"'
arch=('i686' 'x86_64')
url='http://abuse.zoy.org/'
license=('GPL' 'custom:PublicDomain')
depends=('gcc-libs' 'libgl' 'sdl' 'sdl_mixer')
install='abuse.install'
source=("http://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}.tar.gz")

# Remove the unfree 'claudio' addon
# $ source PKGBUILD
# $ mksource
mksource() {
    pushd /tmp >/dev/null

    wget http://abuse.zoy.org/raw-attachment/wiki/download/${pkgname%-libre}-${pkgver}.tar.gz \
         -O - | tar xzf -

    rm -rvf ./abuse-$pkgver/data/addon/claudio
    tar czvf ${pkgname}-${pkgver}.tar.gz ./abuse-$pkgver

    popd >/dev/null

    mv -v /tmp/${pkgname}-${pkgver}.tar.gz .
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr --with-assetdir=/usr/share/abuse/orig --with-x
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  install -d "${pkgdir}/usr/share/licenses/abuse"
  sed -n '1,/^$/p' src/view.cpp > "${pkgdir}/usr/share/licenses/abuse/orig.code.license"
}

md5sums=('10cac59308bff0dadb8437eff8b4d87e')