# $Id: PKGBUILD 104849 2014-01-27 15:16:44Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: mortzu <me@mortzu.de>
# Contributor: fnord0 <fnord0@riseup.net>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=acpi_call
pkgname=acpi_call-libre
pkgver=1.1.0
pkgrel=2
_extramodules=extramodules-3.13-LIBRE
pkgdesc='A linux kernel module that enables calls to ACPI methods through /proc/acpi/call (built for the linux-libre kernel package)'
arch=('i686' 'x86_64')
url="http://github.com/mkottman/${_pkgname}"
license=('GPL')
depends=('linux-libre>=3.13' 'linux-libre<3.14')
makedepends=('linux-libre-headers>=3.13' 'linux-libre-headers<3.14')
replaces="${_pkgname}"
conflicts="${_pkgname}"
provides="${_pkgname}=${pkgver}"
install="${_pkgname}.install"
source=("${url}/archive/v${pkgver}.tar.gz")
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0')

build() {
  cd ${_pkgname}-${pkgver}

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make KVERSION="${_kernver}"
}

package() {
  cd ${_pkgname}-${pkgver}

  install -dm 755 "${pkgdir}"/usr/lib/{modules/${_extramodules},modules-load.d}
  install -m 644 ${_pkgname}.ko "${pkgdir}"/usr/lib/modules/${_extramodules}
  gzip "${pkgdir}"/usr/lib/modules/${_extramodules}/${_pkgname}.ko
  echo ${_pkgname} > "${pkgdir}"/usr/lib/modules-load.d/${_pkgname}.conf

  install -dm 755 "${pkgdir}"/usr/share/${_pkgname}
  cp -dr --no-preserve='ownership' {examples,support} "${pkgdir}"/usr/share/${_pkgname}/
}

# vim: ts=2 sw=2 et: