# Parabola maintainer: Michał Masłowski <mtjm@mtjm.eu>
# $Id: PKGBUILD 135613 2011-08-16 16:22:12Z andrea $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>

_pkgname=kile
pkgname=kile-libre
pkgver=2.1
pkgrel=2
pkgdesc="A user friendly TeX/LaTeX frontend for KDE"
arch=("i686" "x86_64")
license=('GPL2')
url="http://kile.sourceforge.net/"
depends=('kdebase-runtime' 'texlive-core' 'kdebase-kwrite')
makedepends=('cmake' 'automoc4')
conflicts=('kile')
replaces=('kile')
provides=('kile')
install=${_pkgname}.install
source=("http://downloads.sourceforge.net/$_pkgname/$_pkgname-$pkgver.tar.bz2"
        "no-acroread.patch")
sha1sums=('860ac96b68b6026f48b8a9c401c6024ba78e3cdf'
          '9bbe5d1b0e2a78b13667fcf4e5e21f801447f9d6')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  # Don't recommend a nonfree PDF viewer.
  patch -Np1 -i "${srcdir}/no-acroread.patch"
  cd ..
  mkdir build
  cd build
  cmake ../${_pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}