# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=libdrm-libre
pkgver=2.4.39
pkgrel=1
pkgdesc='Userspace interface to kernel DRM services, without VMWare Graphics KMS API (vmwgfx)'
arch=(
  i686
  x86_64
  mips64el
:)
license=(
  MIT
)
depends=(
  libpciaccess
  )
makedepends=(
  cairo
  valgrind
)
options=(
  !libtool
)
url=http://dri.freedesktop.org/
provides=(
  ${pkgname%-libre}=$pkgver
  ${pkgname%-libre}-git
  $pkgname-git
)
conflicts=(
  ${pkgname%-libre}
  ${pkgname%-libre}-git
  $pkgname-git
  ${pkgname%-libre}-new
  ${pkgname%-libre}-nouveau
  ${pkgname%-libre}-old
)
replaces=(
  ${pkgname%-libre}
  ${pkgname%-libre}-git
  ${pkgname%-libre}-new
  ${pkgname%-libre}-nouveau
)

source=(
  http://dri.freedesktop.org/${pkgname%-libre}/${pkgname%-libre}-$pkgver.tar.bz2
  COPYING
)
sha512sums=(
  51b849d501adbf6c9d65847d2e6b41e426137af8cdb1335d19e22939128b7cdae8685c27d750db3aad7b1c43e7bb5a448634491dcd86873ba98293d56320eb1f
  b0ca349b882a4326b19f81f22804fabdb6fb7aef31cdc7b16b0a7ae191bfbb50c7daddb2fc4e6c33f1136af06d060a273de36f6f3412ea326f16fa4309fda660
)

build() {
  cd ${pkgname%-libre}-$pkgver

  sed -i '/PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)/d;/AC_SUBST(PTHREADSTUBS_CFLAGS)/d;/AC_SUBST(PTHREADSTUBS_LIBS)/d' \
    configure.ac
  sed -i '/	$(PTHREADSTUBS_CFLAGS) /d;s/ @PTHREADSTUBS_LIBS@//' \
    exynos/Makefile.am
  sed -i '/	$(PTHREADSTUBS_CFLAGS) /d;/	@PTHREADSTUBS_LIBS@ /d' \
    intel/Makefile.am
  sed -i '/	$(PTHREADSTUBS_CFLAGS) /d;s/ @PTHREADSTUBS_LIBS@//' \
    nouveau/Makefile.am
  sed -i '/	$(PTHREADSTUBS_CFLAGS) /d;s/ @PTHREADSTUBS_LIBS@//' \
    omap/Makefile.am
  sed -i '/	$(PTHREADSTUBS_CFLAGS) /d;s/ @PTHREADSTUBS_LIBS@//' \
    radeon/Makefile.am

  #libtoolize --force
  autoreconf --force --install
  ./configure --prefix=/usr \
    --disable-vmwgfx-experimental-api \
    --enable-udev
  make V=0
}

check() {
cd ${pkgname%-libre}-$pkgver
  make -k check
}

package() {
cd ${pkgname%-libre}-$pkgver
  make DESTDIR=$pkgdir install
  install -m755 -d $pkgdir/usr/share/licenses/${pkgname%-libre}
  install -m644 ../COPYING $pkgdir/usr/share/licenses/${pkgname%-libre}
}