# Maintainer: Joshua Haase <hahj87@gmail.com
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>

pkgbase=libretools
pkgname=(libretools libretools-pr libretools-mips64el)
pkgver=20121107
pkgdesc="Scripts for Parabola development"
url="http://parabolagnulinux.org"
license=('GPL3+')

pkgrel=1
arch=('any')
depends=(openssh rsync git wget devtools)
install=libretools.install
source=(https://projects.parabolagnulinux.org/$pkgbase.git/snapshot/$pkgbase-$pkgver.tar.bz2)

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  make
}

package_libretools() {
  backup=(etc/libretools.conf)

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools DESTDIR="$pkgdir"
  install -Dm755 rePKGBUILD.proto ${pkgdir}/usr/share/pacman/rePKGBUILD.proto
}

package_libretools-pr() {
  backup=('etc/libretools.d/prtools.conf')

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools-pr DESTDIR="$pkgdir"
}

package_libretools-mips64el() {
  backup=('etc/libretools.d/mips64el.conf')

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools-mips64el DESTDIR="$pkgdir"
}

md5sums=('d80cc433cc627b2d7aa1c37f794d2ef9')