# $Id$
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Contributor: bitlord

pkgbasename=liferea
pkgname=liferea-libre
pkgver=1.6.6b
pkgrel=1
pkgdesc="A desktop news aggregator for online news feeds and weblogs"
arch=('i686' 'x86_64' 'mips64el')
url="http://liferea.sourceforge.net/"
provides=("liferea=$pkgver")
replaces=('liferea')
conflicts=('liferea')
license=('GPL')
depends=('gconf' 'libwebkit' 'libxslt' 'libglade' 'sqlite3' 'hicolor-icon-theme')
makedepends=('pkg-config' 'intltool' 'lua' 'libnotify')
optdepends=('lua: for lua scripting support'
            'libnotify: for notification support')
options=('!libtool' '!emptydirs')
install=liferea.install
source=(http://repo.parabolagnulinux.org/other/$pkgname-$pkgver.tar.gz
        libnotify-0.7.patch
        remove-non-free-suggestions.patch)
md5sums=('3e6a113a30f8d813c3a7ece4691d5afe'
         'fca97e3316c1c51e0179c4c7dcce47a2'
         'e138b67a6bc62d4ba0eb64b781105bf0')

# source PKGBUILD ; mksource
mksource() {
    wget http://downloads.sourceforge.net/sourceforge/liferea/liferea-${pkgver}.tar.gz \
         -O - | tar xzf -

    pushd liferea-$pkgver >/dev/null
    patch -Np1 -i "../remove-non-free-suggestions.patch" || return 1
    popd >/dev/null

    tar cvzf $pkgname-$pkgver.tar.gz liferea-$pkgver/
    rm -rvf liferea-$pkgver/
}

build() {
  cd "${srcdir}/liferea-${pkgver}"
  patch -Np1 -i "$srcdir/libnotify-0.7.patch"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-schemas-install
  make
}

package() {
  cd "${srcdir}/liferea-${pkgver}"
  make DESTDIR="${pkgdir}" install
  
  install -d "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" "${pkgdir}"/etc/gconf/schemas/*.schemas
  rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas
}