# Maintainer: Márcio Silva <coadde@lavabit.com>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
_pkgflag=libre
pkgver=10.0.2
pkgrel=1
pkgdesc='Mesa 3-D OpenCL library'
url=http://${pkgbase}3d.sourceforge.net
license=(MIT Khronos LGPL)
arch=(mips64el x86_64 i686)
depends=(
  libclc
  $pkgbase
)
optdepends='opencl-headers: headers necessary for OpenCL development'
makedepends=(
  clang
  dri2proto
  glproto
  imake
  libxml2
  python2
)
provides=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
conflicts=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
replaces=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
source=ftp://ftp.freedesktop.org/pub/$pkgbase/${pkgver%.0}/${pkgbase^}Lib-$pkgver.tar.bz2
sha512sums=15741b916e6338645a28961fb7a731f8c2a33afe11e91c0bd144f9d9afca96837c9caf7fb2fd769aedbeba2b8b12443e7a7eb8ab6cd2270024308ca11e88ff24

build() {
  cd $srcdir/${pkgbase^}-$pkgver
  autoreconf -vfi
  ./configure --prefix=/usr\
    --enable-opencl\
    --enable-gallium-llvm\
    --enable-r600-llvm-compiler\
    --with-clang-libdir=/usr/lib\
    --with-llvm-shared-libs\
    --with-gallium-drivers=i915,nouveau,r300,r600,radeonsi,svga,swrast
  make V=0
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver
  make -C src/gallium/targets/opencl DESTDIR=$pkgdir install
  install -vdm755 $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}