# $Id: PKGBUILD 70615 2010-02-27 15:46:11Z thayer $
# Maintainer: Thayer Williams <thayer@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
# Contributor: Robson Peixoto

_pkgname=unzip
pkgname=unzip-libre
pkgver=6.0
pkgrel=5.1
pkgrel_orig=5
pkgdesc="Unpacks .zip archives such as those made by PKZIP"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.info-zip.org/"
license=('custom')
depends=('bzip2' 'bash')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
replaces=("${_pkgname}")
source=("https://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}-${pkgrel_orig}-any.src.tar.xz")


build() {
  cd ${srcdir}/${_pkgname}${pkgver/./}

  # set CFLAGS -- from Debian
  export CFLAGS="$CFLAGS -D_FILE_OFFSET_BITS=64 -DACORN_FTYPE_NFS \
  -DWILD_STOP_AT_DIR -DLARGE_FILE_SUPPORT -DUNICODE_SUPPORT \
  -DUNICODE_WCHAR -DUTF8_MAYBE_NATIVE -DNO_LCHMOD -DDATE_FORMAT=DF_YMD \
  -DUSE_BZIP2 -DNATIVE"

  # make -- from Debian
  make -f unix/Makefile LOCAL_UNZIP="$CFLAGS" prefix=/usr LF2="" \
  D_USE_BZ2=-DUSE_BZIP2 L_BZ2=-lbz2 unzips

}

package(){
  cd ${srcdir}/${_pkgname}${pkgver/./}

  # install -- from Debian
  make -f unix/Makefile prefix=${pkgdir}/usr INSTALL_PROGRAM="install" install

  # install the license file
  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/unzip/LICENSE

  # fix manpage location
  mkdir -p ${pkgdir}/usr/share
  mv ${pkgdir}/usr/man ${pkgdir}/usr/share/
}

md5sums=('8e8a774e2006617d8787d095bb78c78a')